KW Ermittlung in Excel 2007

Question

Hallo Leute,

Ich habe eine Excel Tabele vor mir mit genau 53 Registerblättern(für jede Woche im Jahr eines),die folgendes fordert.
Trage ich in Zelle A1 "2009" ein,so soll mir in Zelle A2 angezeigt werden,z.B.01.01.-04.01. Im Registerblatt KW2 soll dann in A2 erscheinen 05.01.-11.01. usw.
Lässt sich sowas irgendwie realisieren?
Vielen Dank für Eure Tipps.

Gruß Lextor!

Answer 1

Hallo Lextor...
hab mal ein bißchen gespielt... soweit es mein Wissen zuläßt :-)
Also Blatt 'KW1' Zelle A2 folgende Formel:

=TAG((("01.01."&A1)-WOCHENTAG("01.01."&A1;2)+1))&"."&MONAT((("01.01."&A1)-WOCHENTAG("01.01."&A1;2)+1))&".-"&TAG((("01.01."&A1)-WOCHENTAG("01.01."&A1;2)+1)+6)&"."&MONAT((("01.01."&A1)-WOCHENTAG("01.01."&A1;2)+1)+6)

Blatt 'KW2' ZelleA2:

=TAG((("01.01."&A1)-WOCHENTAG("01.01."&A1;2)+1)+[7])&"."&MONAT((("01.01."&A1)-WOCHENTAG("01.01."&A1;2)+1+[7]))&".-"&TAG((("01.01."&A1)-WOCHENTAG("01.01."&A1;2)+1)+[13])&"."&MONAT((("01.01."&A1)-WOCHENTAG("01.01."&A1;2)+1)+[13])

Die Zahlen in den eckigen Klammern für jede weitere Kw um 7 erhöhen.
Also Auf dem Blatt 'KW3' für die beiden 7 eine 14; für die beiden 13 eine 20... usw.
Die eckigen Klammern in der richtigen Formel natürlich weglassen...
is nur zur Markierung.
Falls Du nicht klar kommst, oder noch ein Fehler drinsteckt... melden.

Gruß
Kauz

Answer 2

Hallo Lextor,

für A2 gilt folgende Formel

=TEXT(("4.1."&A1)+TEIL(ZELLE("Dateiname";$A$1);FINDEN("]";ZELLE("Dateiname";$A$1))+3;31)*1*7-7-REST("2.1."&A1;7);"TT.MM.-")&TEXT(("4.1."&A1)+TEIL(ZELLE("Dateiname";$A$1);FINDEN("]";ZELLE("Dateiname";$A$1))+3;31)*1*7-7-
REST("2.1."&A1;7)+6;"TT.MM.")

Bedingung:
Die Tabellenblätter müssen die Namen KW1, KW2, KW3,....KW10,.....KW53 haben, ohne Leerzeichen.

Für die 1. KW 2009 muss es übrigens richtig heißen: 29.12.-04.01.

Gruß
Rainer

Answer 3

Hallo,

Ich danke Euch für EureTipps.
Ich werde versuchen diese umzusetzten,und dann gebe ich natürlich eine Rückmeldung an Euch.

Gruß Lextor!

Answer 4

Hallo Rainer,

Das hat super funktioniert.Ich habe die Formel kopiert,das war am einfachsten für mich.Denn ich verstehe die Formel nicht.Aber es funktioniert.Vielen Dank.

p.s. falls du mal Zeit hast würde ich mich über eine kleine verständliche erläuterung freuen.Einen schönen Sonntag.

Gruß Lextor!

Answer 5

Hallo Lextor,

eine genaue Erklärung würde zu weit führen, daher nur folgende Hinweise.

Um das richtige Datum für das gewünschte Ergebnis zu erzeugen, brauchst Du eine Jahreszahl und eine Kalenderwoche.
Die Jahreszahl hast Du vor gegeben und die Kalenderwoche wird aus dem Tabellennamen extrahiert.

Die Grundformel zum Auslesen des Tabellennamens findest Du hier

sie lautet

=TEIL(ZELLE("Dateiname";$A$1);FINDEN("]";ZELLE("Dateiname";$A$1))+1;31)

Die Grundformel zum Erzeugen eines Datums aus einer Jahreszahl und einer Kalenderwoche findest Du hier

sie lautet

=("4.1."&A2)+A1*7-7-REST("2.1."&A2;7)

Diese beiden Formeln habe ich so zusammen geschraubt, dass mit Hilfe der Funktion TEXT(), Dein relativ anspruchsvolles Ergebnis entsteht.

Für mehr Erklärung fehlt mir leider Lust und Zeit.

Gruß
Rainer

Answer 6

Danke Dir.