Summe anhand eines Wortes als Basiswert

Question

Hallo, brauche Hilfe. Ich habe zwei Excel Tabellen. In Tabelle 1 in Spalte B stehen immer verschiedene Texte, wie z.B. Buch, Stft, Klebe, untereinander. Die 2. Tabelle soll z. B. in Spalte E soll mir ausgeben: Wenn in Spalte B das Wort Stift steht, dann addiere 1 dazu in Spalte E der Tabelle 2. Die Tabelle 2 Soll auch auf einem anderen Tabellenblatt zu finden sein.
Kann mir jemand helfen?
Vielen Dank vorab.

Answer 1

Hallo Rosalie,

könntest Du mal den Sachverhalt so schildern, dass derjenige der Deine Datei nicht sieht, weis, was gemeint ist?

Gruß
Rainer

Answer 2

Hallo Rosalie,

so ganz verstehe ich auch nicht, was du willst.

Wenn du wissen willst, wie oft z.B. das Wort "Stift" in Spalte B der Tabelle 1 vorkommt, so kannst du das mit der folgenden Formel:

=ZÄHLENWENN(Tabelle1!B:B;"Stift")

Ansonsten schließe ich mich Rainer an.

Gruß

M.O.

Answer 3

Ja, sorry, bisl kompliziert ausgedrückt. Ich möchte eine Summe in Tabelle 2 bilden, wenn in Tabelle 1 in einer Spalte ein bestimmtes Wort steht.
Ich habe halt eine Tabelle in der untereinander die verschiedenen Artikel stehen. Diese will ich gezählt haben in einer anderen Tabelle. Also immer wenn Stift in Tabelle 1 steht, dann soll sich die Gesamtsumme "Anzahlt Stifte" in der 2. Tabelle wiedergeben. Und das halt mit den verschiedenen Artikeln.
War das etwas verständlicher ausgedrückt ;)
.

Answer 4

Hallo Rosalie,

da lag ich mit meiner Formel gar nicht so falsch.
Du kannst sie entsprechend abändern, so dass du z.B. in Tabelle 2 Spalte A die entsprechenden Suchbegriffe schreibst und in Spalte B die folgende Formel:

=ZÄHLENWENN(Tabelle1!B:B;A1)

Die Formel zählt dann, wie oft das Wort, das in A1 steht, in Tabelle 1, Spalte B vorkommt.

Gruß

M.O.

Answer 5

Hallo Rosalie,

ich gehe davon aus, dass in Tabelle1!B3:B4000 Deine verschiedenen Dinge stehen, dass in Tabelle2 in Spalte D ab D3 alle in Tabelle1 vorkommenden Dinge je einmal aufgeführt werden und in Tabelle2 in Spalte E ab E3 die dazugehörigen Anzahlen stehen sollen. Dann schreibe

in Tabelle2!D3:
=Tabelle1!B3

in Tabelle2!D4 die Matrixformel (mit STRG + UMSCH + ENTER eingeben!):
=WENN(ISTFEHLER(INDEX(Tabelle1!$B$3:$B$4000; VERGLEICH(1; (ZÄHLENWENN(Tabelle2!$D$3:D3; Tabelle1!$B$3:$B$4000) = 0) * (Tabelle1!$B$3:$B$4000 <> ""); 0))); ""; INDEX(Tabelle1!$B$3:$B$4000; VERGLEICH(1; (ZÄHLENWENN(Tabelle2!$D$3:D3; Tabelle1!$B$3:$B$4000) = 0) * (Tabelle1!$B$3:$B$4000 <> ""); 0)))
und kopiere/ziehe die Formel so weit runter wie nötig. Ein paar mehr Zeilen als jetzt verschiedene Teile vorhanden sind können es ruhig sein, falls später in Tabelle1 noch neue dazukommen,

in Tabelle2!E3:
=WENN(D3 = ""; ""; ZÄHLENWENN(Tabelle1!$B$3:$B$400000;D3))
Kopiere/ziehe diese Formel genauso weit runter wie die Formel in Spalte D.

MfG Charlotte

Answer 6

Sorry,

zwei Nullen zuviel in der letzten Formel, richtig ist:

in Tabelle2!E3:
=WENN(D3 = ""; ""; ZÄHLENWENN(Tabelle1!$B$3:$B$4000; D3))

Gruß,
Charlotte