Supportnet Computer Supportnet Games Supportnet Kochen Explipedia
Login: guestBesucher online: 295
Supportnet Computerforum
SUPPORT
Home
Forum
Tipps & Infos
Blitz Angebote
Members
Hilfe
Video

TOP THEMEN
SSD Test
Alles über SSDs

Android Tipps
iPad Tipps
Google Tipps
Windows 8 FAQ
Windows 7 FAQ
E-Mail FAQ
Netzwerk FAQ
Festplatten FAQ
Datenrettung FAQ
Bildbearbeitung FAQ

Top iPhone Apps
Computer Einsteiger
Die 5 besten...
Explipedia
Themen
Direktlinks

Neue Einträge
News einsenden News einschicken
Tipps einsenden Tipp einschicken

SN-LINKS

Suche
Befreundete Seiten
Top Seiten

Supportnet/Forum/Tabellenkalkulation



Supportnet/Forum/Tabellenkalkulation
von colatrinkerr. vom 14.02.2017, 16:29 Diese Seite den Supportnet Favoriten hinzufügen  Mißbrauch, Beleidigungen und Blödsinn den Moderatoren melden


Bedingte Formatierung Matrix

 (529 Hits)

Hallo,

ich habe diese Matrixformel in Zelle H2 (Tabellenblatt Aktionsplanung) hinterlegt:

{=WENN($G6<>"";(INDEX(Artikel_Report!$G:$G;VERGLEICH($A6&$H$1;Artikel_Report!$A:$A&Artikel_Report!$E:$E;0))/365)*(INDEX(Artikel_Report!$H:$H;VERGLEICH($A6&$H$1;Artikel_Report!$A:$A&Artikel_Report!$E:$E;0)))*$G6;"")}

Nun möchte ich, dass sich die Zelle H2 rot färbt, wenn auf dem Tabellenblatt Artikelreport in der gesuchten Zeile der Spalte K ein "Z" steht.

Hat jemand eine Lösung für mich, was ich in der bedingten Formatierung eingeben muß?

Vielen Dank, Colatrinkerr.


Antwort schreiben 50 Bonuspunkte

Antworten...
Antwort 1 von colatrinkerr. vom 15.02.2017, 09:30 Mißbrauch, Beleidigungen und Blödsinn den Moderatoren melden

Liebe Excel-Experten,

ich bin nicht sicher, ob meine Frage verständlich ist. Bitte gerne Rückfragen stellen.

Danke.


Antwort noch nicht bewertet
Antwort 2 von M.O. vom 16.02.2017, 08:05 Mißbrauch, Beleidigungen und Blödsinn den Moderatoren melden

Hallo,

was gibt denn die Formel denn aus? Etwas die gesuchte Zeile?
Dann versuch für die bedingte Formatierung die folgende Formel:
=INDIREKT("Artikelreport!K"&H2)="Z"

Gruß

M.O.


Antwort noch nicht bewertet Als gute Antwort bewerten
Diese Antwort hat mein Problem gelöst
Antwort 3 von colatrinkerr. vom 16.02.2017, 11:30 Mißbrauch, Beleidigungen und Blödsinn den Moderatoren melden

Hallo M.O.,

ich habe deine Formel in die Bedingung eingegeben. Die Zellenfarbe verändert sich aber nicht. :-(

Ich versuche mal zu erklären:

In der Tabelle Artikelreport stehen folgende Angaben:
Spalte A, Zeile 2 = 1616 (Art-Nr.)
Spalte E, Zeile 2= 50 (Filiale)
Spalte G, Zeile 2 = 300 (Stück verkauft im Jahr)
Spalte H, Zeile 2 = 100 (Stück verkauft in einem Zeitraum)
Spalte K, Zeile 2 = Z (Klassenkennzeichen)

In der Tabelle Aktionsplanung stehen folgende Angaben:
Spalte A, Zeile 2 = 1616 (Art-Nr.)
Spalte H, Zeile 2 = 10 (Stück)
Zeile 1, Spalte I = 50 (Filiale)
Zeile 2, Spalte I = die genannte Index-Formel. Ich möchte ermitteln, wieviel Stück voraussichtlich in einem gewissen Zeitraum zusätzlich verkauft werden. Die Formel klappt super.
Zeile 1, Spalte J = 66 (Filiale) usw.

Durch die bedingte Formatierung möchte ich zusätzlich visualisieren, ob der errechnete Wert in Zeile 2, Spalte I durch das Klassenkennzeichen (Spalte K Artikelreport) "Z" gekennzeichnet ist.

Gruß,
Colatrinkerr.


Antwort noch nicht bewertet
Antwort 4 von M.O. vom 16.02.2017, 12:33 Mißbrauch, Beleidigungen und Blödsinn den Moderatoren melden

Hallo,

die gepostete Formel für die bedingte Formatierung klappt nur, wenn die von dir gepostete Matirxformel die entsprechende Zeile ausgegeben hätte. Da dies nicht der Fall ist, klappt das natürlich nicht.

Versuch mal die folgende Formel für die bedingte Formel:
=INDEX(Artikel_Report!K:K;VERGLEICH(1;MMULT((Artikel_Report!A:A=A2)*(Artikel_Report!E:E=I1);1);0))="Z"

Gruß

M.O.


Antwort noch nicht bewertet Als gute Antwort bewerten
Diese Antwort hat mein Problem gelöst
Antwort 5 von colatrinkerr. vom 16.02.2017, 13:39 Mißbrauch, Beleidigungen und Blödsinn den Moderatoren melden

Hallo,

super - dankeschön, das hat super geklappt. :-)

Für die Spalte I klappt das super. Ich wollte die Formel jetzt noch auf die Spalten J-W und allen beschriebenen Zeilen anwenden.
Wie kann ich das denn machen?

Gruß,
Colatrinkerr.


Antwort noch nicht bewertet
Antwort 6 von M.O. vom 16.02.2017, 14:02 Mißbrauch, Beleidigungen und Blödsinn den Moderatoren melden

Hallo,

das ist im Prinzip ein SVERWEIS mit zwei Suchkriterien, nämlich die Artikelnummer in A2 und die Filialnummer in I1.
Du musst eigentlich nur das Suchfeld für die Filialnummer - in der geposteten Formel die I1 - entsprechend ändern. Also für Spalte J dann so (wenn ich den Aufbau deiner Tabellen richtig verstanden habe):
=INDEX(Artikel_Report!K:K;VERGLEICH(1;MMULT((Artikel_Report!A:A=A2)*(Artikel_Report!E:E=J1);1);0))="Z"

Den Rest dann entsprechend.

Gruß

M.O.


Antwort noch nicht bewertet Als gute Antwort bewerten
Diese Antwort hat mein Problem gelöst
Antwort 7 von colatrinkerr. vom 16.02.2017, 14:28 Mißbrauch, Beleidigungen und Blödsinn den Moderatoren melden

Hallo,

ok, Spalte I-V machen was sie sollen. Toll :-).

Muß ich für alle darunter liegenden Zeilen eine eigene Bedingung schreiben?
In Zeile 2 wird nämlich nicht A2 und Filiale (Spalte I1) abgefragt, sondern A3 und Filiale (Spalte I1).

Sorry, muß mich langsam rantasten....


Antwort noch nicht bewertet
Antwort 8 von M.O. vom 16.02.2017, 14:53 Mißbrauch, Beleidigungen und Blödsinn den Moderatoren melden

Hallo,

ja, dann musst du statt A2 eben A3 schreiben ;-).

Einfacher ist aber der folgende Weg:
ändere die Formel für Spalte I wie folgt:
=INDEX(Artikel_Report!K:K;VERGLEICH(1;MMULT((Artikel_Report!A:A=A3)*(Artikel_Report!E:E=$I$1);1);0))="Z"

d.h. adressiere I1 absolut.
Dann setze den Cursor in eine Zelle in Spalte I, gehe auf bedingte Formatierung, Regeln verwalten und auf "wird angewendet". Klicke auf das Tabellensymbol. Dann kannst du den Bereich in Spalte I markieren, auf den die bedingte Formatierung angewendet werden soll.
Dass musst du dann entsprechend für die anderen Spalten wiederholen.

Aber Achtung, die Performance könnte darunter leiden.

Gruß

M.O.


Antwort noch nicht bewertet Als gute Antwort bewerten
Diese Antwort hat mein Problem gelöst
Antwort 9 von colatrinkerr. vom 16.02.2017, 15:26 Mißbrauch, Beleidigungen und Blödsinn den Moderatoren melden

Großartig. Vielen lieben Dank.
Dauert jetzt zwar echt lange, aber es klappt wunderbar.

Könntest Du wieder den Button "Als gute Antwort bewerten" klicken?

Colatrinkerr.


Antwort noch nicht bewertet
Antwort 10 von M.O. vom 16.02.2017, 15:45 Mißbrauch, Beleidigungen und Blödsinn den Moderatoren melden

Hallo,

danke für die Rückmeldung. Aber ich werde mich jetzt nicht selber bewerten ;-).

Gruß

M.O.


Antwort noch nicht bewertet Als gute Antwort bewerten
Diese Antwort hat mein Problem gelöst
Antwort 11 von colatrinkerr. vom 22.02.2017, 12:36 Mißbrauch, Beleidigungen und Blödsinn den Moderatoren melden

Hallo M.O.

aufgrund der Performance habe ich mich entschieden, die Tabelle etwas umzubauen.

In der Tabelle Artikelreport stehen folgende Angaben:
Spalte A, Zeile 2 = 1616 (Art-Nr.)
Spalte E, Zeile 2= 50 (Filiale)
Spalte G, Zeile 2 = 300 (Stück verkauft im Jahr)
Spalte H, Zeile 2 = 100 (Stück verkauft in einem Zeitraum)
Spalte K, Zeile 2 = Z (Klassenkennzeichen)

In der Tabelle Aktionsplanung stehen folgende Angaben:
Spalte A, Zeile 2 = 1616 (Art-Nr.)
Spalte H, Zeile 2 = 10 (Stück)
Zeile 1, Spalte H = 50 (Filiale)
Zeile 2, Spalte I = hier soll ein "Z" auftauchen, wenn
im Tabellenblatt Artikelreport im Spalte K ein "Z" steht.

Meine Formel in Zelle I2 lautet:
{=WENNFEHLER(WENN($H2>0;(INDEX(Artikel_Report!K:K;VERGLEICH($A2&$H$1;Artikel_Report!A:A&Artikel_Report!E:E;0))));"")}

Die Formel gibt mir allerdings jeden Wert aus Spalte K wieder, und nicht nur das "Z".

Hast Du eine Idee, wie das geht?

Gruß, Colatrinkerr.


Antwort noch nicht bewertet
Antwort 12 von M.O. vom 22.02.2017, 13:31 Mißbrauch, Beleidigungen und Blödsinn den Moderatoren melden

Hallo,

probier mal die folgende Formel in I2:

=WENN(INDEX(Artikelreport!K:K;VERGLEICH(1;MMULT((Artikelreport!A:A=A2)*(Artikelreport!E:E=H1);1);0))="Z";"Z";"")

Gruß

M.O.


Antwort noch nicht bewertet Als gute Antwort bewerten
Diese Antwort hat mein Problem gelöst
Antwort 13 von colatrinkerr. vom 22.02.2017, 13:47 Mißbrauch, Beleidigungen und Blödsinn den Moderatoren melden

toll !!! du bist echt ein ass!
Vielen Dank.

Gruß, Colatrinkerr


Antwort noch nicht bewertet
Antwort 14 von colatrinkerr. vom 22.02.2017, 15:55 Mißbrauch, Beleidigungen und Blödsinn den Moderatoren melden

Ich nochmal,

ich muß doch noch was ändern. Da ich die Formel noch nicht ganz durchblickt habe, bekomme ich das nicht hin. :-(

Wenn ein "Z" oder eine Null das gesuchte Ergebnis ist, soll ein "!" ausgegeben werden.

Was muß ich dann ändern? Ich verwende jetzt diese Formel:

=WENNFEHLER(WENN(UND(INDEX(Artikel_Report!K:K;VERGLEICH(1;MMULT((Artikelreport!A:A=A2)*(Artikelreport!E:E=H1);1);0))="Z";H2<>"");"!";"");"")


Antwort noch nicht bewertet
Antwort 15 von M.O. vom 22.02.2017, 16:29 Mißbrauch, Beleidigungen und Blödsinn den Moderatoren melden

Hallo,

das mit der Null ist etwas schwieriger, da eine leere Zelle auch als Null interpretiert wird.

Falls die Zelle auf keinen Fall leer sein kann, dann reicht diese Formel:

=WENN(ODER(INDEX(Artikelreport!K:K;VERGLEICH(1;MMULT((Artikelreport!A:A=A2)*(Artikelreport!E:E=H1);1);0))="Z";INDEX(Artikelreport!K:K;VERGLEICH(1;MMULT((Artikelreport!A:A=A2)*(Artikelreport!E:E=H1);1);0))=0);"!";"")

Falls auch leere Zellen vorhanden sein können, dann probier es mal so:

=WENN(ODER(INDEX(Artikelreport!K:K;VERGLEICH(1;MMULT((Artikelreport!A:A=A2)*(Artikelreport!E:E=H1);1);0))="Z";UND(ISTZAHL(INDEX(Artikelreport!K:K;VERGLEICH(1;MMULT((Artikelreport!A:A=A2)*(Artikelreport!E:E=H1);1);0)));INDEX(Artikelreport!K:K;VERGLEICH(1;MMULT((Artikelreport!A:A=A2)*(Artikelreport!E:E=H1);1);0))=0));"!";"")

Gruß

M.O.


Antwort noch nicht bewertet Als gute Antwort bewerten
Diese Antwort hat mein Problem gelöst
Antwort 16 von colatrinnkerr. vom 23.02.2017, 11:22 Mißbrauch, Beleidigungen und Blödsinn den Moderatoren melden

Hallo M.O.

dankeschön :-).
Habe mich entschieden, keine Nullen abzufragen. Klappt wunderbar.

=WENNFEHLER(WENN(UND(INDEX(Prognosegenauigkeit;VERGLEICH(1;MMULT((Art_Nr.=$A2)*(Fil=$H$1);1);0))="schlechte Prognose";H2<>"");"!";"");"")

Gruß
Colatrinkerr.


Antwort noch nicht bewertet




Hinweis
Diese Frage ist schon etwas älter, Sie können daher nicht mehr auf sie antworten. Sollte Ihre Frage noch nicht gelöst sein, stellen Sie einfach eine neue Frage im Forum.

MACHEN SIE IHRE WEBSITE ATTRAKTIVER
Sie haben eine eigene Website und wollen Ihre Besucher auf den Supportnet-Service aufmerksam machen? Kopieren Sie einfach den Quellcode in Ihre Seite und jeder Besucher Ihrer Seite kann direkt auf die Supportnet-Datenbank zugreifen.

My Supportnet


SUCHE

Gruppen im Forum
Betriebsysteme
Software
Hardware
Netzwerk
Programmierung
Sonstiges

Impressum © 1997-2015 SupportNet
Version: supportware 1.8.230E / 18.10.2010, Startzeit:Fri Dec 8 16:26:13 2017