Wenn Bild im Verzeichnis vorhanden, dann ja sonst nein

Question

Guten Morgen Supportnet :)

ich habe das Inet schon noch einer brauchbaren Lösung gesucht aber nichts gefunden. Habe immernoch die Excel Version 2002 und möchte sie auch nicht eintauschen.
Wäre jemand so nett mir bei meinem Problem zu helfen?

In meiner Tabelle sind in den Zeilen 1 und 2 die Überschriften, die Daten beginnen ab Zeile 3.
Habe einen Ordner auf der Festplatte die Bilder enthält, die genauso beschriftet sind wie in Spalte "AL" nur hier ohne die Endung ".jpg".
In Spalte "AZ" würde ich gerne wissen mit ja oder nein, ob das Bild mit dem Namen aus "AL" im Ordner auf der Festplatte vorhanden ist.

Würde das mit einer Formel gehen oder doch mit Makro?

Internette Grüsse
Mick

Answer 1

Hallo Mick,

ob das mit Formel geht, weiß ich nicht, aber per Makro ganz bestimmt.

Das folgende Makro gehört in ein Standard Modul deiner Arbeitsmappe. Den Pfad, in dem die Bilder liegen, musst du entsprechend anpassen. Das Makro muss aus dem Arbeitsblatt heraus gestartet werden, in deine Bildnamen stehen:

Sub bilder_vorhanden()

Dim strPfad As String
Dim strDatei As String
Dim lngLetzte As Long
Dim lngZeile As Long

'Pfad in dem die Bilder liegen - anpassen
strPfad = "C:\Test\"

With ActiveSheet

'letzte beschriebene Zeile in Spalte AL ermitteln
lngLetzte = .Cells(Rows.Count, 38).End(xlUp).Row

For lngZeile = 3 To lngLetzte
strDatei = strPfad & .Cells(lngZeile, 38).Value & ".jpg" 'Pfad und Bildname generieren
'prüfen, ob Bild vorhanden ist

If Len(Dir(strDatei)) = 0 Then
.Cells(lngZeile, 52) = "nein"
Else
.Cells(lngZeile, 52) = "ja"
End If

Next lngZeile

End With

End Sub

Gruß

M.O.

Answer 2

Hallo Community .-)

Noch zur Ergänzung!

Gruss Nighty

Rückgabewert False/True

Function DateiJaNein(Zelle As Range) As Boolean
If CreateObject("Scripting.FileSystemObject").GetFile("J:\temp\" & Zelle).Name = Zelle Then DateiJaNein = True
End Function

Answer 3

Lieber M.O.,

dufte :) funktioniert ja einwandfrei, herzlichen Dank dafür!!!

Und Dir Nighty auch lieben Dank! Wo muss ich Deine Ergänzung zwischenschieben?

Internette Grüsse
Mick